В этом уроке мы научимся создавать свою собственную подсветку ambilight для телевизора своими руками с помощью Arduino Nano.
Имейте в виду, что Эмбилайт Ардуино будет работать только на ПК с программным обеспечением Bambilight (скачать библиотеку на GitHub).
Шаг 1. Комплектующие Ambilight Arduino
Вам понадобятся следующие компоненты:
- Индивидуально адресуемая светодиодная лента RGB
- Ардуино Нано
- Макетная плата небольшого размера
- Несколько кабелей
- 12V DC адаптер питания
- Двусторонний скотч
- 4-5 Скрепки
- Затяжки (стяжки) пластиковые для проводов
Шаг 2. Тестирование светодиодной ленты
Будет неприятно, если вы сначала установите ленту на ваш телевизор, но потом поймете, что один светодиод не работает и вам придется удалять ленту и начинать всё сначала.
Поэтому неплохо припаять временные провода к вашей светодиодной ленте и протестировать ее с помощью Arduino, адаптера питания и файла .ino (можно загрузить на следующих шагах). Загрузите .ino в свой Arduino. Здесь вам пока еще ничего не нужно настраивать. Вы должны увидеть несколько меняющихся цветов светодиодной ленты.
Шаг 3. Схема подключения
Вы можете подключить светодиодную ленту, используя изображение выше, представленное на этом шаге.
Наша светодиодная лента использует IC WS2811 для управления 3 светодиодами в отдельности.
Шаг 4. Установка ambilight на монитор/телевизор
Перед тем, как приклеить светодиодную ленту эмбилайт ардуино к задней панели монитора или телевизора, обязательно очистите поверхность как можно лучше. Чтобы избавиться от пыли лучше использовать волокнистую ткань.
Как только вы убедитесь, что поверхность чистая, вы можете измерить длину светодиодной ленты, удерживая ее рядом с вашим монитором и отрезая ее до нужного размера. Убедитесь, что полоса на противоположной стороне имеет одинаковую длину.
После того, как вы отрезали все отрезки в нужном размере, вы можете прикрепить их к задней панели монитора. Поскольку клей обычно не является лучшим вариантом, предлагаем использовать некоторые кусочки двустороннего скотча.
Убедитесь, что стрелки на светодиодных полосах направлены вокруг вашего монитора! Если нет вам придется начать все заново!
Как только ленты на месте, вы сможете установить Arduino Nano на тыльную сторону монитора. Не забудьте установить её в удобное место, потому что вам нужно будет подключить USB-кабель к компьютеру позже.
Шаг 5. Пайка всей электроники
Чтобы припаять светодиодную ленту мы использовали несколько скрепок, которые согнули и отрезали до соответствующего размера. После этого припаяли их к светодиодным полоскам, чтобы соединить их вместе. Для предотвращения коротких замыканий вы можете использовать некоторые изоляторы, но в нашем случае нам это не было нужно. Чтобы всё выглядело немного лучше, мы использовали маркер, чтобы придать скрепкам черный цвет.
Теперь подключите светодиодную ленту к Arduino, используя ту же схему, что и на шаге выше. Подключите USB-кабель, установите библиотеку FastLED (скачать на GitHub) и загрузите код, указанный на следующем шаге, в ваш Arduino. А далее вам останется только подключить адаптер питания, так как мы сделали всю проводку.
Шаг 6. Скетч Arduino Ambilight
Ниже вы можете скачать или скопировать код для нашей подсветки Ардуино Эмбилайт.
#include "FastLED.h"
#define NUM_LEDS 38
#define LED_DATA_PIN 3
#define NUM_BYTES (NUM_LEDS*3) // 3 colors
#define BRIGHTNESS 100
#define UPDATES_PER_SECOND 100
#define TIMEOUT 3000
#define MODE_ANIMATION 0
#define MODE_AMBILIGHT 1
uint8_t mode = MODE_ANIMATION;
byte MESSAGE_PREAMBLE[] = { 0x00, 0x01, 0x02, 0x03, 0x04, 0x05, 0x06, 0x07, 0x08, 0x09 };
uint8_t PREAMBLE_LENGTH = 10;
uint8_t current_preamble_position = 0;
unsigned long last_serial_available = -1L;
uint8_t led_counter = 0;
uint8_t byte_counter = 0;
CRGB leds[NUM_LEDS];
byte buffer[NUM_BYTES];
// Filler animation attributes
CRGBPalette16 currentPalette = RainbowColors_p;
TBlendType currentBlending = LINEARBLEND;
uint8_t startIndex = 0;
void setup()
{
Serial.begin(115200);
FastLED.clear(true);
FastLED.addLeds<WS2811, LED_DATA_PIN, GRB>(leds, NUM_LEDS);
FastLED.setBrightness(BRIGHTNESS);
}
void loop()
{
switch (mode) {
case MODE_ANIMATION:
fillLEDsFromPaletteColors();
break;
case MODE_AMBILIGHT:
processIncomingData();
break;
}
}
void processIncomingData()
{
if (waitForPreamble(TIMEOUT))
{
Serial.readBytes(buffer, NUM_BYTES);
/* DEBUG
for (int i = 0; i < NUM_BYTES; i++)
{
Serial.write((char)buffer[i]);
}
*/
while (byte_counter < NUM_BYTES)
{
byte green = buffer[byte_counter++];
byte blue = buffer[byte_counter++];
byte red = buffer[byte_counter++];
leds[led_counter++] = CRGB(red, green, blue);
}
FastLED.show();
byte_counter = 0;
led_counter = 0;
}
else
{
mode = MODE_ANIMATION;
}
}
bool waitForPreamble(int timeout)
{
last_serial_available = millis();
while (current_preamble_position < PREAMBLE_LENGTH)
{
if (Serial.available() > 0)
{
last_serial_available = millis();
if (Serial.read() == MESSAGE_PREAMBLE[current_preamble_position])
{
current_preamble_position++;
}
else
{
current_preamble_position = 0;
}
}
if (millis() - last_serial_available > timeout)
{
return false;
}
}
current_preamble_position = 0;
return true;
}
void fillLEDsFromPaletteColors()
{
startIndex++; // speed
uint8_t colorIndex = startIndex;
for( int i = 0; i < NUM_LEDS; i++) {
leds[i] = ColorFromPalette(currentPalette, colorIndex, BRIGHTNESS, currentBlending);
colorIndex += 3;
}
FastLED.delay(1000 / UPDATES_PER_SECOND);
if (Serial.available() > 0)
{
mode = MODE_AMBILIGHT;
}
}
Шаг 7. Настройка программного обеспечения
Загрузите файл bambilight.ino (ссылка и сам код вы найдете на предыдущем шаге).
Откройте файл .ino и отредактируйте следующие строки, чтобы они соответствовали вашей ситуации:
#define NUM_LEDS 38 // количество светодиодов #define BRIGHTNESS 100 // яркость
Теперь загрузите скетч в Arduino. Ранее вы должны были скачать библиотеку Bambilight, но если вы этого не сделали вы можете скачать библиотеку на GitHub сейчас.
Откройте Bambilight.exe, расположенную в:
[Местоположение, где вы сохранили папку Bambilight] \ Bambilight-master \ Bambilight-master \ Binary
Теперь настройте всё по своему усмотрению и протестируйте, используя тестовое видео, например, такое:
Как только вы будете удовлетворены результатом, вы можете минимизировать программу Bambilight.
В целом у вас должен быть такой результат работы подсветки ambilight для телевизора, которую вы сделали своими руками с помощью Arduino. Возьмите попкорн, пепси и наслаждайтесь результатом.