Монитор сердечного ритма с помощью Arduino и платформы Thingspeak IoT

В этом проекте мы собираемся создать систему обнаружения и контроля сердечного ритма с использованием Arduino, которая будет определять сердечный ритм с помощью импульсного датчика и покажет показания в BPM (Beats Per Minute, Ударов в минуту). Он также отправит показания на сервер ThingSpeak с помощью модуля ESP8266 Wi-Fi Bee, так что все показатели можно будет отслеживать из любой точки мира через Интернет.

ThingSpeak - отличный источник для отображения данных в Интернете, и вы можете получить доступ к данным ThingSpeak в любое время и в любом месте.

Шаг 1: Необходимые компоненты

Устройства:

• Arduino UNO Rev3
• Плата расширения для Arduino (I/O Expansion Shield)
• Датчик сердечного ритма
• ESP8266 WiFi Bee

Программное обеспечение:

• Arduino IDE
• API Thingspeak

Шаг 2: Настройка ThingSpeak

ThingSpeak предоставляет очень хороший инструмент для проектов на основе IoT. Используя сайт ThingSpeak, мы можем отслеживать наши данные и управлять нашей системой через Интернет, используя Каналы и веб-страницы, предоставляемые ThingSpeak.

ThingSpeak «Собирает» (Collects) данные от датчиков, «Анализирует и визуализирует» (Analyze and Visualize) данные и «Действует» (Acts) инициируя реакцию. Мы еще используем ThingSpeak в проекте метеостанции с использованием Raspberry Pi и используя Arduino, чтобы узнать больше о ThingSpeak. Здесь мы кратко объясняем использование ThingSpeak для этой системы обнаружения и мониторинга сердцебиения. Служба ThingSpeak управляется MathWorks.

Прежде всего, пользователю необходимо создать учетную запись на ThingSpeak.com, затем войти в систему и нажать «Начать».

После создания учетной записи перейдите в Channels и создайте новый канал. Теперь напишите имя канала и имена полей. Также поставьте галочку в поле «Сделать общедоступным» (Make Public) ниже в форме и, наконец, сохраните канал. Теперь ваш новый канал создан. Выше на фото мы показали некоторые скриншоты ThingSpeak с созданием канала и API ключа.

Шаг 3: Схема и пояснение

ESP8266 WiFi Bee

Wifi Bee-ESP8266 - это модуль Serial-to-WIFI с использованием конструкции XBEE в компактном размере, совместимый со слотом XBEE, применимый к целой системе с одним чипом 3,3 В.

Он может использоваться для Arduino, беспроводной передачи данных, дистанционного управления. Встроенный коммутатор можно использовать для простого выбора модуля запуска или обновления прошивки. Модуль ESP8266 Arduino имеет мощную встроенную технологию обработки и хранения, встроенный 32-битный процессор, встроенный стек протокола Lwip. Поддержка режима AP + STA со-существует.

Модуль датчика сердечного ритма

Датчик сердечного ритма DFRobot представляет собой монитор сердечного ритма большого пальца, разработанный для микроконтроллеров Arduino.

Этот датчик контроля сердечного ритма является импульсным датчиком, который разработан на основе методов PPG. Это простой и недорогой оптический метод, который можно использовать для определения изменения объема крови в микрососудистом слое тканей. В соответствии с этой теорией относительно легко обнаружить пульсирующий компонент сердечного цикла.

Датчик имеет два отверстия, которые можно использовать для крепления к ремню. Вы можете обернуть палец, запястье, мочку уха или другие области, где он контактирует с вашей кожей (на фото выше).

Плата расширения (I/O Expansion Shield)

Чтобы соединить эти компоненты с Arduino, нам нужна Плата расширения, которая легко соединяет их с микроконтроллером.

3.1 Соединение

1. Закрепите/соедините Плату расширения с Arduino UNO.
2. Возьмите модуль датчика сердечного ритма и поместите ремень через отверстия в модулях, чтобы вы могли обернуть палец, запястье, мочку уха или другие области, где он контактирует с вашей кожей.
3. Подключите модуль датчика частоты пульса к выходу A1 на аналоговых выходах Платы расширения. Обратите внимание на цвета выходов и проводов, то есть от красного до красного и т.д.
4. В разъем Wifi Bee на плате разместите ESP8266 WiFi Bee.

Шаг 4: Код, загрузка и тестирование

1. Оберните ремень вокруг пальца или запястья.
2. Теперь загрузите эскиз для тестирования модуля в первый раз.
3. Откройте серийный плоттер, подождите 5 секунд и будьте спокойны. Вы увидите график сердечных ударов.
4. Попытайтесь заблокировать кровоток другой рукой.
5. Линия графика станет прямой, после в течение некоторого времени и достигнет нормальной стадии, так как кровь найдет способ для циркуляции, если все капилляры не заблокированы должным образом.

• Теперь загрузите основной код в Arduino.
• Не забудьте изменить ключ API, SSID (имя WiFi) и PASS (Пароль) для вашего проекта. Используйте датчик сердечного ритма сначала на себе. ESP8266 затем свяжется с Arduino и отправит данные в ThingSpeak.

ESP8266 подключится к сети вашего маршрутизатора, которую вы предоставите в коде, и будет отправлять данные датчика онлайн. Эти данные на ThingSpeak будут показаны в форме графика, отображающего прошлые результаты, и к ним можно получить доступ из любого места в Интернете.

Шаг 5: Эскизы (скетчи) для Ардуино

Ниже вы можете скопировать код для Arduino IDE или скачать файлы .ino.

main_code.ino

#include <SoftwareSerial.h>
#include <stdlib.h>

#define DEBUG true
SoftwareSerial esp8266(9,10); 
#define SSID "Your Wifi Name"     // "SSID-WiFiname" 
#define PASS "Your Wifi Password"       // "password"
#define IP "184.106.153.149"// thingspeak.com ip

String msg = "GET /update?key=9YS21NU0HY5YS1IKU"; //change it with your api key like "GET /update?key=Your Api Key"

//Variables
float temp;
int hum;
String tempC;
int error;
int pulsePin = 0;         // Pulse Sensor purple wire connected to analog pin 0
int blinkPin = 13;        // pin to blink led at each beat
int fadePin = 5;
int fadeRate = 0;

// Volatile Variables, used in the interrupt service routine!
volatile int BPM;           // int that holds raw Analog in 0. updated every 2mS
volatile int Signal;              // holds the incoming raw data
volatile int IBI = 600;     // int that holds the time interval between beats! Must be seeded! 
volatile boolean Pulse = false;     // "True" when heartbeat is detected. "False" when not a "live beat". 
volatile boolean QS = false;        // becomes true when Arduino finds a beat.

// Regards Serial OutPut  -- Set This Up to your needs
static boolean serialVisual = true;   // Set to 'false' by Default.  Re-set to 'true' to see Arduino Serial Monitor ASCII Visual Pulse 
volatile int rate[10];                    // array to hold last ten IBI values
volatile unsigned long sampleCounter = 0;          // used to determine pulse timing
volatile unsigned long lastBeatTime = 0;           // used to find IBI
volatile int P =512;                  // used to find peak in pulse wave, seeded
volatile int T = 512;               // used to find trough in pulse wave, seeded
volatile int thresh = 525;  // used to find instant moment of heart beat, seeded
volatile int amp = 100;     // used to hold amplitude of pulse waveform, seeded
volatile boolean firstBeat = true;        // used to seed rate array so we startup with reasonable BPM
volatile boolean secondBeat = false;      // used to seed rate array so we startup with reasonable BPM

void setup()  {
  Serial.begin(9600); //or use default 115200.
  esp8266.begin(9600);
  Serial.println("AT");
  esp8266.println("AT");
  delay(5000);
  if(esp8266.find("OK"))  {
    connectWiFi();
  }
  interruptSetup(); 
}

void loop() {
  start: //label 
  error=0;
  updatebeat();
  //Resend if transmission is not completed 
  if (error==1) {
    goto start; //go to label "start"
  }
  
  delay(1000); 
}

void updatebeat() {
  String cmd = "AT+CIPSTART=\"TCP\",\"";
  cmd += IP;
  cmd += "\",80";
  Serial.println(cmd);
  esp8266.println(cmd);
  delay(2000);
  if(esp8266.find("Error")) {
    return;
  }
  cmd = msg ;
  cmd += "&field1=";   
  cmd += BPM;
  cmd += "\r\n";
  Serial.print("AT+CIPSEND=");
  esp8266.print("AT+CIPSEND=");
  Serial.println(cmd.length());
  esp8266.println(cmd.length());
  if(esp8266.find(">")) {
    Serial.print(cmd);
    esp8266.print(cmd);
  }
  else{
   Serial.println("AT+CIPCLOSE");
   esp8266.println("AT+CIPCLOSE");
    //Resend...
    error=1;
  }
}

boolean connectWiFi() {
  Serial.println("AT+CWMODE=1");
  esp8266.println("AT+CWMODE=1");
  delay(2000);
  String cmd="AT+CWJAP=\"";
  cmd+=SSID;
  cmd+="\",\"";
  cmd+=PASS;
  cmd+="\"";
  Serial.println(cmd);
  esp8266.println(cmd);
  delay(5000);
  if(esp8266.find("OK"))  {
    Serial.println("OK");
    return true;    
  }else {
    return false;
  }
}

void interruptSetup() {     
  TCCR2A = 0x02;     // DISABLE PWM ON DIGITAL PINS 3 AND 11, AND GO INTO CTC MODE
  TCCR2B = 0x06;     // DON'T FORCE COMPARE, 256 PRESCALER 
  OCR2A = 0X7C;      // SET THE TOP OF THE COUNT TO 124 FOR 500Hz SAMPLE RATE
  TIMSK2 = 0x02;     // ENABLE INTERRUPT ON MATCH BETWEEN TIMER2 AND OCR2A
  sei();             // MAKE SURE GLOBAL INTERRUPTS ARE ENABLED      
} 
ISR(TIMER2_COMPA_vect)  {                // triggered when Timer2 counts to 124
  cli();                                 // disable interrupts while we do this
  Signal = analogRead(pulsePin);              // read the Pulse Sensor 
  sampleCounter += 2;                         // keep track of the time in mS
  int N = sampleCounter - lastBeatTime;       // monitor the time since the last beat to avoid noise
    //  find the peak and trough of the pulse wave
  if(Signal < thresh && N > (IBI/5)*3){      // avoid dichrotic noise by waiting 3/5 of last IBI
    if (Signal < T){                         // T is the trough
      T = Signal;                            // keep track of lowest point in pulse wave 
    }
  }
  if(Signal > thresh && Signal > P){        // thresh condition helps avoid noise
    P = Signal;                             // P is the peak
  }                                         // keep track of highest point in pulse wave
  
  //  NOW IT'S TIME TO LOOK FOR THE HEART BEAT
  // signal surges up in value every time there is a pulse
  if (N > 250){                                   // avoid high frequency noise
    if ( (Signal > thresh) && (Pulse == false) && (N > (IBI/5)*3) ){        
      Pulse = true;                               // set the Pulse flag when there is a pulse
      digitalWrite(blinkPin,HIGH);                // turn on pin 13 LED
      IBI = sampleCounter - lastBeatTime;         // time between beats in mS
      lastBeatTime = sampleCounter;               // keep track of time for next pulse
      if(secondBeat){                        // if this is the second beat
        secondBeat = false;                  // clear secondBeat flag
        for(int i=0; i<=9; i++){             // seed the running total to get a realistic BPM at startup
          rate[i] = IBI;                      
        }
      }
      if(firstBeat){                         // if it's the first time beat is found
        firstBeat = false;                   // clear firstBeat flag
        secondBeat = true;                   // set the second beat flag
        sei();                               // enable interrupts again
        return;                              // IBI value is unreliable so discard it
      }   
      word runningTotal = 0;                  // clear the runningTotal variable    
      for(int i=0; i<=8; i++){                // shift data in the rate array
        rate[i] = rate[i+1];                  // and drop the oldest IBI value 
        runningTotal += rate[i];              // add up the 9 oldest IBI values
      }
      rate[9] = IBI;                          // add the latest IBI to the rate array
      runningTotal += rate[9];                // add the latest IBI to runningTotal
      runningTotal /= 10;                     // average the last 10 IBI values 
      BPM = 60000/runningTotal;               // how many beats can fit into a minute? that's BPM!
      QS = true;                              // set Quantified Self flag 
      // QS FLAG IS NOT CLEARED INSIDE THIS ISR
    }                       
  }
  if (Signal < thresh && Pulse == true){   // when the values are going down, the beat is over
    digitalWrite(blinkPin,LOW);            // turn off pin 13 LED
    Pulse = false;                         // reset the Pulse flag so we can do it again
    amp = P - T;                           // get amplitude of the pulse wave
    thresh = amp/2 + T;                    // set thresh at 50% of the amplitude
    P = thresh;                            // reset these for next time
    T = thresh;
  }
  if (N > 2500){                           // if 2.5 seconds go by without a beat
    thresh = 512;                          // set thresh default
    P = 512;                               // set P default
    T = 512;                               // set T default
    lastBeatTime = sampleCounter;          // bring the lastBeatTime up to date        
    firstBeat = true;                      // set these to avoid noise
    secondBeat = false;                    // when we get the heartbeat back
  }
  sei();     
  // enable interrupts when youre done!
}

testing_heart_sensor.ino

int sensorPin = A1;   //for analog input
//remember you put the switch towards 'A' not 'D' for analog input

void setup()  {
  Serial.begin(115200);
  //default is 9600, change after opening the serial plotter
 }

void loop()  {
  int heartValue = analogRead(heartPin);    //reading the analog value
  Serial.println(heartValue);   //printing the value tot the serial plotter
  delay(5);
  }

Скачать main_code.ino

Скачать testing_heart_sensor.ino

На этом всё. Хороших вам проектов.