Делаем пульсоксиметр с питанием от USB на Arduino

Делаем недорогой пульсоксиметр с питанием от USB на основе платы Arduino Nano R3 с использованием OLED-дисплея.

Комплектующие

Для разработки пульсоксиметр на основе Ардуино на понадобятся следующие компоненты оборудования:

1. Arduino Nano R3 × 1
2. Высокочувствительный пульсоксиметр и датчик сердечного ритма MAX30102 × 1
3. Дисплей DFRobot Gravity I2C OLED-2864 × 1

Программное обеспечение:

• Arduino IDE
• Autodesk Fusion 360

Ручные инструменты:

• 3D-принтер (универсальный)
• Паяльник (универсальный)

Остановимся подробнее на комплектующих:

MAX30102

128x64 Pixel OLED

Arduino Nano R3

По работе с платой Ардуино Нано у нас есть очень большой мастер-класс по этой ссылке.

О проекте

Идея проекта возникла из-за ситуации с COVID-19. Это заболевание, вызываемое вирусом SARS-CoV-2, поражает, прежде всего, дыхательную систему человека. Некоторые более легкие симптомы могут включать лихорадку, боли и озноб, но также может привести к более серьезным проблемам, таким как пневмония.

Человек, у которого есть пневмония или даже небольшая одышка, может не понимать, когда ему лучше обратиться за помощью. Так и появилась идея создания пульсоксиметра с открытым исходным кодом, который может помочь людям получить необходимую помощь и точную информацию об их текущем состоянии.

Давайте опишем принцип действия пульсоксиметра, который приведен в Википедии:

В основу метода положено 2 явления. Во-первых, поглощение гемоглобином (Hb) света двух различных по длине волн меняется в зависимости от насыщения его кислородом. Во-вторых, световой сигнал, проходя ткани, приобретает пульсирующий характер вследствие изменения объёма артериального русла при каждом сердечном сокращении.

Пульсоксиметр имеет периферический датчик, в котором находится источник света двух длин волн — 660 нм («красный») и 940 нм («инфракрасный»). Степень поглощения зависит от того, насколько гемоглобин крови насыщен кислородом (каждая молекула Hb способна присоединить максимум 4 молекулы кислорода). Фотодетектором регистрируются изменения цвета крови в зависимости от этого показателя. Усреднённое наполнение отображается монитором пульсоксиметра.

Распечатываем детали

Для работы можно использовать файлы из архива в формате .stl:

Собираем схему

Наше устройство создано на основе Arduino Nano, которая закрепляется на кусок картона размером 44 на 30 мм. Сначала провода припаиваются к контактам VIN, GND, SDA и SCL датчика.

Разъем для OLED подключается к Nano, а затем идет к самому дисплею.

Наконец, вся электроника собирается в корпусе и закрепляется с помощью пары винтов 3 мм.

Сборка устройства

Электроника вставляется в корпус. Размещаем экран OLED на верхней части корпуса и закрепляем его с помощью пары винтов 3 мм. Вы можете осторожно наклонить крышку вверх и вниз для проверки закрепления экрана.

Скетч для пульсоксиметра

Скетч ниже выполняет несколько действий для отображения текущего пульса пользователя и степени насыщения кислородом. Чтобы загрузить его, просто установите необходимые библиотеки и выберите Arduino Nano в списке плат в меню "Инструменты" (Tools) и нажмите "Загрузить" (Upload).

Нам понадобятся следующие библиотеки:

• max3010x
• wire
• SSD1306

Эскиз сначала инициализирует OLED и MAX30102, сообщая при этом о любых ошибках, которые могут возникнуть. Затем он считывает 100 значений для калибровки датчика и начинает отображать их. Затем устройство входит в цикл, где оно считывает 25 новых значений и вычисляет среднее. Наконец, он проверяет правильность значений и выводит их на экран, если они есть.

#include <Wire.h>
#include "MAX30105.h"
#include "spo2_algorithm.h"
#include "SSD1306Ascii.h"
#include "SSD1306AsciiWire.h"

MAX30105 particleSensor;
SSD1306AsciiWire oled;

#define MAX_BRIGHTNESS 255

#if defined(__AVR_ATmega328P__) || defined(__AVR_ATmega168__)
//Arduino Uno doesn't have enough SRAM to store 50 samples of IR led data and red led data in 32-bit format
//To solve this problem, 16-bit MSB of the sampled data will be truncated. Samples become 16-bit data.
uint16_t irBuffer[50]; //infrared LED sensor data
uint16_t redBuffer[50];  //red LED sensor data
#else
uint32_t irBuffer[50]; //infrared LED sensor data
uint32_t redBuffer[50];  //red LED sensor data
#endif

int32_t spo2; //SPO2 value
int8_t validSPO2; //indicator to show if the SPO2 calculation is valid
int32_t heartRate; //heart rate value
int8_t validHeartRate; //indicator to show if the heart rate calculation is valid

void setup()
{
  Serial.begin(115200); // initialize serial communication at 115200 bits per second:

  oled.begin(&Adafruit128x64, 0x3C);
  oled.setFont(Arial14);

  // Initialize sensor
  if (!particleSensor.begin(Wire, I2C_SPEED_FAST)) //Use default I2C port, 400kHz speed
  {
    Serial.println(F("MAX30105 was not found. Please check wiring/power."));
    while (1);
  }

  particleSensor.setup(55, 4, 2, 200, 411, 4096); //Configure sensor with these settings
}

void loop()
{

  //read the first 50 samples, and determine the signal range
  for (byte i = 0 ; i < 50 ; i++)
  {
    while (particleSensor.available() == false) //do we have new data?
      particleSensor.check(); //Check the sensor for new data

    redBuffer[i] = particleSensor.getRed();
    irBuffer[i] = particleSensor.getIR();
    particleSensor.nextSample(); //We're finished with this sample so move to next sample
    Serial.print(F("red="));
    Serial.print(redBuffer[i], DEC);
    Serial.print(F(", ir="));
    Serial.println(irBuffer[i], DEC);
  }

  //calculate heart rate and SpO2 after first 50 samples (first 4 seconds of samples)
  maxim_heart_rate_and_oxygen_saturation(irBuffer, 50, redBuffer, &spo2, &validSPO2, &heartRate, &validHeartRate);

  //Continuously taking samples from MAX30102.  Heart rate and SpO2 are calculated every 1 second
  while (1)
  {
    //dumping the first 25 sets of samples in the memory and shift the last 25 sets of samples to the top
    for (byte i = 25; i < 50; i++)
    {
      redBuffer[i - 25] = redBuffer[i];
      irBuffer[i - 25] = irBuffer[i];
    }

    //take 25 sets of samples before calculating the heart rate.
    for (byte i = 25; i < 50; i++)
    {
      while (particleSensor.available() == false) //do we have new data?
        particleSensor.check(); //Check the sensor for new data

      redBuffer[i] = particleSensor.getRed();
      irBuffer[i] = particleSensor.getIR();
      particleSensor.nextSample(); //We're finished with this sample so move to next sample
      Serial.print(F("red="));
      Serial.print(redBuffer[i], DEC);
      Serial.print(F(", ir="));
      Serial.print(irBuffer[i], DEC);

      Serial.print(F(", HR="));
      Serial.print(heartRate, DEC);

      Serial.print(F(", HRvalid="));
      Serial.print(validHeartRate, DEC);

      Serial.print(F(", SPO2="));
      Serial.print(spo2, DEC);

      Serial.print(F(", SPO2Valid="));
      Serial.println(validSPO2, DEC);
      
    }

    //After gathering 25 new samples recalculate HR and SP02
    maxim_heart_rate_and_oxygen_saturation(irBuffer, 50, redBuffer, &spo2, &validSPO2, &heartRate, &validHeartRate);
    printToScreen();
  }
}

void printToScreen() {
  oled.clear();
  oled.setCursor(0,0);
  if(validSPO2 && validHeartRate) {
    oled.print(F("HR: ")); oled.println(heartRate, DEC);
    oled.print(F("SPO2: ")); oled.println(spo2, DEC);
  } else {
    oled.print(F("Not valid"));
  }
}

Чтобы использовать пульсоксиметр, поместите кончик пальца поверх датчика и аккуратно закройте верхнюю крышку. Затем подключите источник питания и просто подождите, пока не увидите отображаемые данные.

Оригинал статьи - hackster.io. Мнение редакции ArduinoPlus.ru может не совпадать с с мнением автора оригинальной статьи.