Связываем Arduino с датчиком расхода жидкости

В этом уроке мы свяжем микроконтроллер Arduino Uno с датчиком расхода жидкости для измерения расхода воды.

Вы когда-нибудь хотели измерить жидкость, протекающую через трубу, или создать систему управления, основанную на расходе или количестве воды? Например, вы можете использовать это во время работы в саду, чтобы измерить количество воды, используемой для полива растений, чтобы предотвратить потери или не перекормить растения. Если да, то этот довольно простой проект для вас. Ниже приведены пошаговые инструкции по измерению расхода и количества воды с помощью датчика расхода и Arduino.

Как работает датчик расхода жидкости?

Датчик расхода жидкости работает по принципу эффекта Холла. Эффект Холла — явление возникновения поперечной разности потенциалов (называемой также холловским напряжением) при помещении проводника с постоянным током в магнитное поле.

Согласно эффекту Холла, в проводнике индуцируется разность напряжений, поперечная к электрическому току, а магнитное поле перпендикулярно к нему. Здесь в датчике расхода жидкости для эффекта Холла используется небольшой ротора в форме вентилятора/пропеллера, который расположен на пути потока жидкости.

Жидкость толкает ребра ротора, заставляя его вращаться. Вал ротора соединен с датчиком Холла. Это расположение токопроводящей катушки и магнита, соединенного с валом ротора, поэтому напряжение / импульс индуцируется при вращении этого ротора. В этом расходомере на каждый литр жидкости, проходящей через него в минуту, он выдает около 4,5 импульсов. Это связано с изменяющимся магнитным полем, вызванным магнитом, прикрепленным к валу ротора, как показано на рисунке ниже. Мы измеряем количество импульсов, используя Arduino, а затем рассчитываем скорость потока в литрах в час (л/час), используя простую формулу преобразования, объясненную в шаге 2.

Подключение Arduino к датчику

Соединения, необходимые для этого датчика расхода воды относительно Arduino, очень минимальны. От датчика расхода идет только три провода. Линия 5 В VCC (красный провод), GND (черный провод) и линия сигнал/импульс (signal/pulse, обычно желтый). Подключите VCC и GND расходомера к VCC и GND Arduino. Импульсная линия датчика расхода соединена с цифровым выводом Arduino 2. Цифровой вывод 2 Arduino служит внешним выводом прерывания (вывод прерывания 0). И это всё, вы подключили свой расходомер к Arduino!

Загрузка кода расходомера в Arduino и измерение расхода воды

Ниже вы можете скачать или скопировать код Ардуино датчика расхода воды:

byte statusLed    = 13;

byte sensorInterrupt = 0;  // 0 = digital pin 2
byte sensorPin       = 2;

// The hall-effect flow sensor outputs approximately 4.5 pulses per second per
// litre/minute of flow.
float calibrationFactor = 4.5;

volatile byte pulseCount;  

float flowRate;
unsigned int flowMilliLitres;
unsigned long totalMilliLitres;

unsigned long oldTime;

void setup()
{
  
  // Initialize a serial connection for reporting values to the host
  Serial.begin(38400);
   
  // Set up the status LED line as an output
  pinMode(statusLed, OUTPUT);
  digitalWrite(statusLed, HIGH);  // We have an active-low LED attached
  
  pinMode(sensorPin, INPUT);
  digitalWrite(sensorPin, HIGH);

  pulseCount        = 0;
  flowRate          = 0.0;
  flowMilliLitres   = 0;
  totalMilliLitres  = 0;
  oldTime           = 0;

  // The Hall-effect sensor is connected to pin 2 which uses interrupt 0.
  // Configured to trigger on a FALLING state change (transition from HIGH
  // state to LOW state)
  attachInterrupt(sensorInterrupt, pulseCounter, FALLING);
}

/**
 * Main program loop
 */
void loop()
{
   
   if((millis() - oldTime) > 1000)    // Only process counters once per second
  { 
    // Disable the interrupt while calculating flow rate and sending the value to
    // the host
    detachInterrupt(sensorInterrupt);
        
    // Because this loop may not complete in exactly 1 second intervals we calculate
    // the number of milliseconds that have passed since the last execution and use
    // that to scale the output. We also apply the calibrationFactor to scale the output
    // based on the number of pulses per second per units of measure (litres/minute in
    // this case) coming from the sensor.
    flowRate = ((1000.0 / (millis() - oldTime)) * pulseCount) / calibrationFactor;
    
    // Note the time this processing pass was executed. Note that because we've
    // disabled interrupts the millis() function won't actually be incrementing right
    // at this point, but it will still return the value it was set to just before
    // interrupts went away.
    oldTime = millis();
    
    // Divide the flow rate in litres/minute by 60 to determine how many litres have
    // passed through the sensor in this 1 second interval, then multiply by 1000 to
    // convert to millilitres.
    flowMilliLitres = (flowRate / 60) * 1000;
    
    // Add the millilitres passed in this second to the cumulative total
    totalMilliLitres += flowMilliLitres;
      
    unsigned int frac;
    
    // Print the flow rate for this second in litres / minute
    Serial.print("Flow rate: ");
    Serial.print(int(flowRate));  // Print the integer part of the variable
    Serial.print(".");             // Print the decimal point
    // Determine the fractional part. The 10 multiplier gives us 1 decimal place.
    frac = (flowRate - int(flowRate)) * 10;
    Serial.print(frac, DEC) ;      // Print the fractional part of the variable
    Serial.print("L/min");
    // Print the number of litres flowed in this second
    Serial.print("  Current Liquid Flowing: ");             // Output separator
    Serial.print(flowMilliLitres);
    Serial.print("mL/Sec");

    // Print the cumulative total of litres flowed since starting
    Serial.print("  Output Liquid Quantity: ");             // Output separator
    Serial.print(totalMilliLitres);
    Serial.println("mL"); 

    // Reset the pulse counter so we can start incrementing again
    pulseCount = 0;
    
    // Enable the interrupt again now that we've finished sending output
    attachInterrupt(sensorInterrupt, pulseCounter, FALLING);
  }
}

/*
Insterrupt Service Routine
 */
void pulseCounter()
{
  // Increment the pulse counter
  pulseCount++;
}

Загрузите код расходомера в свой Arduino. Код использует внешнее прерывание на цифровом выводе Arduino 2. Он используется для считывания импульсов, поступающих от расходомера. Когда Arduino обнаруживает импульс, он немедленно запускает функцию pulseCounter(). Эта функция затем подсчитывает общее количество импульсов.

В этом датчике расхода Arduino на каждый литр жидкости, проходящей через него в минуту, он выдает около 4,5 импульсов. Разделив общее число импульсов на 4,5, вы получите общее количество жидкости, проходящей через него, в литрах в минуту. Умножив это на 60, вы получите скорость потока в литрах в час, которая даст нам общее количество или количество воды/жидкости, прошедшей через него. Датчик с точностью до 3%.

Используйте этот датчик расхода жидкости Arduino с электромагнитным клапаном для контроля и управления используемой водой. Вы можете использовать его в своей садовой системе или связать с ЖК-дисплеем для других приложений, требующих измерения расхода и количества воды. Удачи с вашим новым проектом Arduino!