Arduino EEPROM: энергонезависимая память

Arduino – это целое семейство различных устройств для создания электронных проектов. Микроконтроллеры очень удобны для использования, доступны к освоению даже новичку. Каждый микроконтроллер состоит из платы, программ для обеспечения работы, памяти. В этой статье будет рассмотрена энергонезависимая память, используемая в Arduino.

Описание памяти EEPROM

Ардуино предоставляет своим пользователям три типа встроенной памяти устройств: стационарное ОЗУ (оперативно-запоминающее устройство или SRAM — static random access memory) – необходимо для записи и хранения данных в процессе использования; флеш-карты – для сохранения уже записанных схем; EEPROM – для хранения и последующего использования данных.

На ОЗУ все данные стираются, как только происходит перезагрузка устройства либо отключается питание. Вторые две сохраняют всю информацию до перезаписи и позволяют извлекать ее при необходимости. Флеш-накопители достаточно распространены в настоящее время. Подробнее стоит рассмотреть память EEPROM.

Аббревиатура расшифровывается, как Electrically Erasable Programmable Read-Only Memory и в переводе на русский дословно означает – электрически стираемая программируемая память только для чтения. Производитель гарантирует сохранность информации на несколько десятилетий вперед после последнего отключения питания (обычно приводят срок в 20 лет, зависит от скорости снижения заряда устройства).

При этом нужно знать, что возможность перезаписи на устройство ограничена и составляет не более 100 000 раз. Поэтому рекомендуют аккуратно и внимательно относиться к вносимым данным и не допускать перезаписи лишний раз.

Объем памяти, в сравнении с современными носителями, очень небольшой и разный для различных микроконтроллеров. Например, для:

  • ATmega328 – 1кБ
  • ATmega168 и ATmega8 – 512 байт,
  • ATmega2560 и ATmega1280 – 4 кБ.

Так устроено потому, что каждый микроконтроллер предназначен для определенного объема задач, имеет разное количество выводов для подключения, соответственно, необходим разный объем памяти. При этом такого количества достаточно для обычно создаваемых проектов.

Для записи на EEPROM требуется значительное количество времени – около 3 мс. Если в момент записи отключается питание, данные не сохраняются вовсе либо могут быть записаны ошибочно. Требуется всегда дополнительно проверять внесенную информацию, чтобы избежать сбоев во время работы. Считывание данных происходит гораздо быстрее, ресурс памяти от этого не снижается.

Библиотека

Работа с памятью EEPROM осуществляется с помощью библиотеки, которая была специально создана для Ардуино. Главными являются способность к записи и чтению данных. Библиотека активируется командой #include EEPROM.h.

Далее используются простые команды:

  • для записи – EEPROM.write(address, data);
  • для чтения – EEPROM.read(address).

В данных скетчах: address – аргумент с данными ячейки, куда вносятся данные второго аргумента data; при считывании используется один аргумент address, который показывает, откуда следует читать информацию.

Функция Назначение
read(address) считывает 1 байт из EEPROM; address – адрес, откуда считываются данные (ячейка, начиная с 0);
write(address, value) записывает в память значение value (1 байт, число от 0 до 255) по адресу address;
update(address, value) заменяет значение value по адресу address, если её старое содержимое отличается от нового;
get(address, data) считывает данные data указанного типа из памяти по адресу address;
put(address, data) записывает данные data указанного типа в память по адресу address;
EEPROM[address] позволяет использовать идентификатор "EEPROM" как массив, чтобы записывать данные в память и считывать их из памяти.

Запись целых чисел

Запись целых чисел в энергонезависимую память EEPROM осуществить достаточно просто. Внесение чисел происходит с запуском функции EEPROM.write(). В скобках указываются необходимые данные. При этом числа от 0 до 255 и числа свыше 255 записываются по-разному. Первые вносятся просто – их объем занимает 1 байт, то есть одну ячейку. Для записи вторых необходимо использовать операторов highByte() высший байт и lowByte() низший байт.

Число делится на байты и записывается отдельно по ячейкам. Например, число 789 запишется в две ячейки: в первую пойдет множитель 3, а во вторую – недостающее значение. В итоге получается необходимое значение:

3 * 256 + 21 = 789

Для «воссоединения» большого целого числа применяется функция word(): int val = word(hi, low). Нужно читывать, что максимальное целое число для записи – 65536 (то есть 2 в степени 16). В ячейках, в которых еще не было иных записей, на мониторе будут стоять цифры 255 в каждой.

Запись чисел с плавающей запятой и строк

Числа с плавающей запятой и строк – это форма записи действительных чисел, где они представляются из мантиссы и показателя степени. Запись таких чисел в энергонезависимую память EEPROM производится с активацией функции EEPROM.put(), считывание, соответственно, – EEPROM.get().

При программировании числовые значения с плавающей запятой обозначаются, как float, стоит отметить, что это не команда, а именно число. Тип Char (символьный тип) – используется для обозначения строк. Процесс записи  чисел на мониторе запускается при помощи setup(), считывание – с помощью loop().

В процессе на экране монитора могут появиться значения ovf, что значит «переполнено», и nan, что значит «отсутствует числовое значение». Это говорит о том, что записанная в ячейку информация не может быть воспроизведена, как число с плавающей точкой. Такой ситуации не возникнет, если достоверно знать, в какой ячейке какой тип информации записан.

Примеры проектов и скетчей

Пример №1

Скетч запишет до 16 символов с последовательного порта и в цикле выведет 16 символов из EEPROM. Благодаря Arduino IDE данные записываются в EEPROM и контролируется содержимое энергонезависимой памяти.

// проверка работы EEPROM
#include <EEPROM.h>
int i, d;

void setup() {
    Serial.begin(9600); // инициализируем порт, скорость 9600
}

void loop() {
  // чтение EEPROM и вывод 16 данных в последовательный порт
  Serial.println();
  Serial.print("EEPROM= ");
  i= 0; while(i < 16) {  
  Serial.print((char)EEPROM.read(i));
  i++;    
  }
  
  // проверка есть ли данные для записи
  if ( Serial.available() != 0 ) {
    delay(50);  // ожидание окончания приема данных

    // запись в EEPROM
    i= 0; while(i < 20) {  
    d= Serial.read();
    if (d == -1) d= ' ';  // если символы закончились, заполнение пробелами 
    EEPROM.write(i, (byte)d);   // запись EEPROM
    i++;
    }      
  }  
  delay(500);
}

Пример №2

Для большего понимания мы можем создать небольшой скетч, который поможет в понимании работы с энергонезависимой памятью. Считаем все ячейки этой памяти. Если ячейка не пустая - вывод в последовательный порт. После чего заполняем ячейки пробелами. Потом вводим текст через монитор последовательного порта. Его записываем в EEPROM, и при последующем включении считываем.

#include <EEPROM.h>
 
int address = 0;                                     // адрес eeprom
int read_value = 0;                                  // считываемые с eeprom данные
char serial_in_data;                                 // данные последовательного порта
int led = 6;                                         // линия 6 для светодиода
int i;
void setup()
{
  pinMode(led, OUTPUT);                               // линия 6 настраивается на выход
  Serial.begin(9600);                                 // скорость передачи по последовательному порту 9600
  Serial.println();
  Serial.println("PREVIOUS TEXT IN EEPROM :-");
  for(address = 0; address < 1024; address ++)        // считываем всю память EEPROM
  {  
    read_value = EEPROM.read(address);
    Serial.write(read_value);
  }
  Serial.println();
  Serial.println("WRITE THE NEW TEXT : ");
  
  for(address = 0; address < 1024; address ++)        // заполняем всю память EEPROM пробелами
    EEPROM.write(address, ' ');                 
  
  for(address = 0; address < 1024; )                  // записываем пришедшие с последовательного порта данные в память EEPROM
  {
    if(Serial.available())
    {
      serial_in_data = Serial.read();  
      Serial.write(serial_in_data); 
      EEPROM.write(address, serial_in_data); 
      address ++;
      digitalWrite(led, HIGH);       
      delay(100);
      digitalWrite(led, LOW);
    }
  }
}
 
void loop()
{
  //---- мигаем светодиодом каждую секунду -----//
  digitalWrite(led, HIGH);       
  delay(1000);
  digitalWrite(led, LOW);
  delay(1000);
}

Пример №3

Запись в память два целых числа, чтение их из EEPROM и вывод в последовательный порт. Числа от 0 до 255 занимают 1 байт памяти,  с помощью функции EEPROM.write() записываются в нужную ячейку. Для чисел больше 255 их нужно делить на байты с помощью highByte() и lowByte() и записывать каждый байт в свою ячейку. Максимальное число при этом – 65536 (или 216).

#include <EEPROM.h> // подключаем библиотеку EEPROM

void setup() {
  int smallNum = 123; // целое число от 0 до 255
  EEPROM.write(0, smallNum); // запись числа в ячейку 0
    
  int bigNum = 789; // число > 255 разбиваем на 2 байта (макс. 65536)
  byte hi = highByte(bigNum); // старший байт
  byte low = lowByte(bigNum); // младший байт
  EEPROM.write(1, hi);  // записываем в ячейку 1 старший байт
  EEPROM.write(2, low); // записываем в ячейку 2 младший байт
 
  Serial.begin(9600); // инициализация послед. порта
}

void loop() {
  for (int addr=0; addr<1024; addr++) { // для всех ячеек памяти (для Arduino UNO 1024)
    byte val = EEPROM.read(addr); // считываем 1 байт по адресу ячейки
    Serial.print(addr); // выводим адрес в послед. порт 
    Serial.print("\t"); // табуляция
    Serial.println(val); // выводим значение в послед. порт
  }

  delay(60000); // задержка 1 мин
}

Пример №4

Запись чисел с плавающей запятой и строк - метод EEPROM.put(). Чтение – EEPROM.get().

#include <EEPROM.h> // подключаем библиотеку

void setup() {
  int addr = 0; // адрес 
  float f = 3.1415926f; // число с плавающей точкой (типа float)
  EEPROM.put(addr, f); // записали число f по адресу addr
  
  addr += sizeof(float); // вычисляем следующую свободную ячейку памяти
  char name[20] = "Hello, SolTau.ru!"; // создаём массив символов
  EEPROM.put(addr, name); // записываем массив в EEPROM 
  Serial.begin(9600); // инициализация послед. порта
}

void loop() {
  for (int addr=0; addr<1024; addr++) { // для всех ячеек памяти (1024Б=1кБ)
    Serial.print(addr); // выводим адрес в послед. порт 
    Serial.print("\t"); // табуляция
    float f; // переменная для хранения значений типа float
    EEPROM.get(addr, f); // получаем значение типа float по адресу addr    
    Serial.print(f, 5); // выводим с точностью 5 знаков после запятой
    Serial.print("\t"); // табуляция

    char c[20]; // переменная для хранения массива из 20 символов
    EEPROM.get(addr, c); // считываем массив символов по адресу addr
    Serial.println(c); // выводим массив в порт
  }

  delay(60000); // ждём 1 минуту
}

Пример №5

Использование EEPROM как массива.

#include <EEPROM.h>

void setup() {
  EEPROM[0] = 11;  // записываем 1-ю ячейку
  EEPROM[1] = 121; // записываем 2-ю ячейку
  EEPROM[2] = 141; // записываем 3-ю ячейку
  EEPROM[3] = 236; // записываем 4-ю ячейку
  Serial.begin(9600);
}

void loop() {
  for (int addr=0; addr<1024; addr++) { 
    Serial.print(addr);
    Serial.print("\t");
    int n = EEPROM[addr]; // считываем ячейку по адресу addr
    Serial.println(n);    // выводим в порт
  }
  
  delay(60000);
}

Работа с EEPROM

Как упоминалось ранее, ресурс памяти EEPROM ограничен. Для продления срока службы энергонезависимой памяти, вместо функции write() запись, лучше применять функцию update обновление. При этом перезапись ведется только для тех ячеек, где значение отличается от вновь записываемого.

Еще одной полезной функцией рассматриваемой памяти микроконтроллера является возможность использования ячеек хранения байтов, как деталей целостного массива EEPROM. При любом формате использования необходимо постоянно осуществлять контроль целостности записанных данных.

Такая память на Ардуино стандартно хранит самое важное для работы контроллера и устройства. К примеру, если на такой базе создается регулятор температуры и исходные данные окажутся ошибочными, устройство будет работать «неадекватно» существующим условиям – сильно занижать или завышать температуру.

Существует несколько ситуаций, когда память EEPROM содержит неправильные данные:

  1. При первоначальной активации – еще не было ни одной записи.
  2. В момент неконтролируемого отключения питания – часть или все данные не запишутся или запишутся некорректно.
  3. После завершения возможных циклов перезаписи данных.

Чтобы избежать возникновения неприятных последствий, устройство можно запрограммировать на несколько вариантов действий: применить данные аварийного кода, отключить систему полностью, подать сигнал о неисправности, использовать заранее созданную копию или другие.

Для контроля целостности информации используют контрольный код системы. Он создается по образцу записи первоначальных данных и, при проверке, он вновь просчитывает данные. Если результат отличается – это ошибка. Самым распространенным вариантом такой проверки является контрольная сумма – выполняется обычная математическая операция по сложению всех значений ячеек.

Опытные программисты добавляют к этому коду дополнительное «исключающее ИЛИ», например, E5h. В случае если все значения равны нулю, а система по ошибке обнулила исходные данные – такая хитрость выявит ошибку.

Таковы основные принципы работы с энергонезависимой памятью EEPROM для микроконтроллеров Arduino. Для определенных проектов стоит использовать только этот вид памяти. Он имеет как свои плюсы, так и свои недостатки. Для освоения методов записи и чтения лучше начать с простых задач.

Ардуино+